Wikidata:SPARQL query service/queries/examples/Peru

From Wikidata
Jump to navigation Jump to search
Other languages:

Introducción

El objetivo de esta página es mostrar la utilidad de SPARQL para obtener datos de Wikidata. Así, alguien familiarizado con Perú tendrá un alcance más amigable al uso de SPARQL en Wikidata.

Contribuciones

Hay diversas maneras como puedes contribuir a esta página según tu conocimiento de SPARQL

  • Conocimiento básico de SPARQL: Propon consultas enfocadas en Perú en la sección Ideas para consultas.

Preferiblemente, el nombre de las variables y los comentarios deben ser escritos en español, ya que estas consultas probablemente serán leídas por peruanos que no tienen conocimiento de inglés.

Consultas

Misceláneo

¿En qué lugar nacen y fallecen las personas con nacionalidad peruana?

#defaultView:Map{"hide":["?placeCoords", "?line", "?rgb"]}
SELECT ?item ?itemLabel ?place ?placeLabel ?placeCoords ?layer ?line ?rgb
WITH {
  SELECT DISTINCT ?item {
    ?item wdt:P27 wd:Q419.
  }
} AS %0
WITH {
  SELECT ?item ?birth ?birthCoords ?birthCoordsLo ?birthCoordsLa ?death ?deathCoords ?deathCoordsLo ?deathCoordsLa {
    INCLUDE %0.
    ?item
      p:P19 [
        ps:P19 ?birth;
        wikibase:rank wikibase:NormalRank;
        ps:P19/p:P625 [
          ps:P625 ?birthCoords;
          psv:P625 [
            wikibase:geoLongitude ?birthCoordsLo;
            wikibase:geoLatitude ?birthCoordsLa
          ]
        ]
      ];
      p:P20 [
        ps:P20 ?death;
        wikibase:rank wikibase:NormalRank;
        ps:P20/p:P625 [
          ps:P625 ?deathCoords;
          psv:P625 [
            wikibase:geoLongitude ?deathCoordsLo;
            wikibase:geoLatitude ?deathCoordsLa
          ]
        ]
      ];
  }
} AS %1
WITH {
  SELECT ?item ?line {
    INCLUDE %1.
    BIND(CONCAT('LINESTRING(', STR(?birthCoordsLo), ' ', STR(?birthCoordsLa), ',', STR(?deathCoordsLo), ' ', STR(?deathCoordsLa), ')') AS ?str).
    BIND(STRDT(?str, geo:wktLiteral) AS ?line).
  }
} AS %2
WITH {
  SELECT
    ?item
    (?birth AS ?place)
    (?birthCoords AS ?placeCoords)
    (?birthCoordsLa AS ?placeCoordsLa)
    (?birthCoordsLo AS ?placeCoordsLo)
    (wdt:P19 AS ?p)
  {
    INCLUDE %1.
  }
} AS %3
WITH {
  SELECT
    ?item
    (?death AS ?place)
    (?deathCoords AS ?placeCoords)
    (?deathCoordsLa AS ?placeCoordsLa)
    (?deathCoordsLo AS ?placeCoordsLo)
    (wdt:P20 AS ?p)
  {
    INCLUDE %1.
  }
} AS %4
{
  {INCLUDE %2}
  UNION
  {INCLUDE %3}
  UNION
  {INCLUDE %4}

  BIND(COALESCE(IF(?p = wdt:P19, "place of birth", 1/0),
                IF(?p = wdt:P20, "place of death", 1/0))
       AS ?layer).
  
  BIND(COALESCE(IF(?p = wdt:P19, "ff0000", 1/0),
                IF(?p = wdt:P20, "000000", 1/0))
       AS ?rgb).

  SERVICE wikibase:label {bd:serviceParam wikibase:language "en"}.
}
Try it!

¿Cuál es la nacionalidad de personas que estudiaron en una universidad ubicada en Perú?

SELECT
  ?nacionalidad
  ?nacionalidadLabel
  ?conteo
WITH {
  SELECT DISTINCT ?universidad {
    ?universidad wdt:P31/wdt:P279* wd:Q3918.
  }
} AS %0
WITH {
  SELECT DISTINCT ?universidad {
    ?universidad wdt:P131* wd:Q419.
  }
} AS %1
# Por alguna razón, conseguir las universidades y luego verificar que
# se encuentran en Perú toma más tiempo que hacer una intersección
# entre los dos conjuntos de universidades.
WITH {
  SELECT ?universidad {
    INCLUDE %0.
    INCLUDE %1.
  }
} AS %2
WITH {
  SELECT DISTINCT ?nacionalidad ?persona ?universidad {
    INCLUDE %2.
    ?persona 
      wdt:P31 wd:Q5;
      wdt:P69 ?universidad;
      wdt:P27 ?nacionalidad.
  }
} AS %3
WITH {
  SELECT ?nacionalidad (COUNT(*) AS ?conteo) {
    INCLUDE %3.
  }
  GROUP BY ?nacionalidad
} AS %4
{
  INCLUDE %4.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es,qu,en"}.
}
ORDER BY DESC(?conteo)
Try it!

¿Cuál es la cantidad de nacimiento de peruanes en Wikidata por mes?

#defaultView:BarChart
SELECT
  ?mesEtiqueta
  ?conteo
# Subconsulta para obtener todos los peruanes que existen en Wikidata
WITH {
  SELECT DISTINCT
    ?peruane
  {
    {?peruane wdt:P27 wd:Q419 }
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruane wdt:P1532 wd:Q419}
  }
} AS %peruane
# Subconsulta para obtener el conteo de nacimientos de peruanos por
# mes
WITH {
  SELECT
    ?mes
    (COUNT(?mes) AS ?conteo)
  {
    INCLUDE %peruane.
    # Usando p:P569 y psv:P569, podemos saber que fechas de nacimiento
    # especifican el mes. Recuerde que cuando la fecha no tiene mes ni
    # dia, entonces la fecha se considera como Enero 1. Mayor
    # información sobre este comportamiento puede ser encontrada en
    # https://phabricator.wikimedia.org/T159160
    #
    # Especificando la precisión, nos podemos asegurar que la fecha de
    # nacimiento tenga, al menos, mes.
    #
    # Mayor información sobre fechas y precisiones puede ser
    # encontrada en
    # https://en.wikibooks.org/wiki/SPARQL/WIKIDATA_Precision,_Units_and_Coordinates
    VALUES ?precisión {10 11}.

    ?peruane p:P569 [
      psv:P569 [
        wikibase:timeValue ?fechaDeNacimiento;
        wikibase:timePrecision ?precisión
      ]
    ].

    LET(?mes := MONTH(?fechaDeNacimiento)).
  }
  GROUP BY ?mes
} AS %conteo
# Subconsulta para convertir el número de un més a su versión
# escrita. Por ejemplo, «1» a «Enero» o «2» a «Febrero».
WITH {
  SELECT
    ?mes
    ?mesEtiqueta
  {
    INCLUDE %conteo.
    LET(?mesEtiqueta := COALESCE(
      IF(?mes = 1, "Enero", 1/0),
      IF(?mes = 2, "Febrero", 1/0),
      IF(?mes = 3, "Marzo", 1/0),
      IF(?mes = 4, "Abril", 1/0),
      IF(?mes = 5, "Mayo", 1/0),
      IF(?mes = 6, "Junio", 1/0),
      IF(?mes = 7, "Julio", 1/0),
      IF(?mes = 8, "Agosto", 1/0),
      IF(?mes = 9, "Septiembre", 1/0),
      IF(?mes = 10, "Octubre", 1/0),
      IF(?mes = 11, "Noviembre", 1/0),
      IF(?mes = 12, "Diciembre", 1/0)
    ))
  }
}
AS %mesEtiqueta
{
  INCLUDE %mesEtiqueta.
  INCLUDE %conteo.
}
Try it!

¿Qué terremotos han ocurrido en alguna parte del Peru?

SELECT DISTINCT
  ?fecha
  ?item
  ?itemLabel
  ?itemDescription
  ?ubicación
  ?ubicaciónLabel
{
  ?item
    wdt:P31/wdt:P279* wd:Q7944;
    wdt:P276/wdt:P131* wd:Q419.
  OPTIONAL{?item wdt:P276 ?ubicación}
  OPTIONAL{?item wdt:P585 ?fecha}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
ORDER BY DESC(?fecha)
Try it!

La consulta de abajo es una versión optimizada. 

SELECT DISTINCT
  ?fecha
  ?terremoto
  ?terremotoLabel
  ?terremotoDescription
  ?ubicación
  ?ubicaciónLabel
WITH {
  SELECT DISTINCT ?terremoto {
    ?terremoto wdt:P276/wdt:P131* wd:Q419.
  }
} AS %0
WITH {
  SELECT DISTINCT ?terremoto {
    INCLUDE %0.
    ?terremoto wdt:P31/wdt:P279* wd:Q7944.
  }
} AS %1
{
  INCLUDE %1.
  OPTIONAL{?terremoto wdt:P276 ?ubicación}.
  OPTIONAL{?terremoto wdt:P585 ?fecha}.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es,qu,en"}.
}
ORDER BY DESC(?fecha)
Try it!

Grupo de usuarios que operan en Perú con sus respectivos grupo de Telegram

SELECT DISTINCT
  ?comunidad
  ?comunidadLabel
  ?comunidadDescription
  ?grupoDeTelegramUsuario
{
  ?comunidad
    wdt:P31/wdt:P279* wd:Q613366;
    wdt:P2541/wdt:P131* wd:Q419.
  OPTIONAL {
    ?grupoDeTelegram
      wdt:P31 wd:Q87410646;
      wdt:P1535 ?comunidad;
      wdt:P3789 ?grupoDeTelegramUsuario.
  }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
Try it!

Peruanos que han ganado competencias internacionales

SELECT DISTINCT
  ?peruano
  ?peruanoLabel
  ?competición_internacional
  ?competición_internacionalLabel
{
  {?peruano wdt:P27 wd:Q419 }
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419 }

  ?competición_internacional
    wdt:P1346 ?peruano;
    wdt:P31/wdt:P279* wd:Q44637051.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
Try it!

Tabla de frecuencia de ocupaciones de peruanos

SELECT
  ?ocupación
  ?ocupaciónLabel
  (COUNT(?ocupaciónLabel) AS ?conteo)
{
  {?peruano wdt:P27 wd:Q419 }
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419 }

  ?peruano wdt:P31 wd:Q5;
           wdt:P106 ?ocupación.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
GROUP BY ?ocupación ?ocupaciónLabel
ORDER BY DESC(?conteo)
Try it!

Mapa de bibliotecas ubicadas en Perú

#defaultView:Map
SELECT DISTINCT
  ?elemento
  ?elementoLabel
  ?coordenadas
{
  ?elemento wdt:P31/wdt:P279* wd:Q7075;
            wdt:P17 wd:Q419;
            wdt:P625 ?coordenadas.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Try it!

La siguiente consulta muestra el tipo de cada una de las bibliotecas. Algunos tipos para bibliotecas son: public library (Q28564), academic library (Q856234) y national library (Q22806). 

#defaultView:Map
SELECT DISTINCT
  ?elemento
  ?elementoLabel
  ?instancia_de_unido
  ?coordenadas
{
  ?elemento wdt:P31/wdt:P279* wd:Q7075;
            wdt:P17 wd:Q419;
            wdt:P625 ?coordenadas;
            rdfs:label ?elementoLabel;
            FILTER(LANG(?elementoLabel) = "es")
  {
    SELECT
    ?elemento
    (GROUP_CONCAT(DISTINCT ?instancia_deLabel; SEPARATOR = ", ") AS ?instancia_de_unido)
    {
      ?elemento wdt:P31/wdt:P279* wd:Q7075;
                wdt:P17 wd:Q419;
                wdt:P31 ?instancia_de.
      ?instancia_de rdfs:label ?instancia_deLabel;
                    FILTER(LANG(?instancia_deLabel) = "es").
    }
    GROUP BY ?elemento
  }
}
Try it!

Peruanos que han recibido premios este año

SELECT
  ?peruano
  ?peruanoLabel
  ?premio
  ?premioLabel
  ?premioDescription
{
  {?peruano wdt:P27 wd:Q419 }
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419 }

  ?peruano
    p:P166 ?enunciado.

  ?enunciado
    ps:P166 ?premio;
    pq:P585 ?fecha.

  FILTER(YEAR(?fecha) = YEAR(NOW()))

  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
ORDER BY ?peruanoLabel
Try it!

Cosas nombradas después de peruanos en otros países

SELECT
  ?país
  ?paísLabel
  ?instancia_deLabel
  ?cosa
  ?cosaLabel
  ?peruano
  ?peruanoLabel
{
  {?peruano wdt:P27 wd:Q419 }
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419 }

  ?cosa wdt:P138 ?peruano;
        wdt:P17 ?país;
        wdt:P31 ?instancia_de.
  
  FILTER(?país != wd:Q419)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
ORDER BY ?paísLabel
Try it!

Mapa de universidades ubicadas en Perú

#defaultView:Map
SELECT DISTINCT
  ?elemento
  ?elementoLabel
  ?coordenadas
{
  ?elemento wdt:P31/wdt:P279* wd:Q3918;
            wdt:P17 wd:Q419;
            wdt:P625 ?coordenadas.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Try it!

Peruanos que cumplen años hoy

SELECT DISTINCT
  ?peruano
  ?peruanoLabel
  ?peruanoDescription
{
  {?peruano wdt:P27 wd:Q419 }
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419 }
  
  FILTER NOT EXISTS {?peruano wdt:P570 ?fecha_de_fallecimiento}

  ?peruano wdt:P569 ?fecha_de_nacimiento.

  FILTER(MONTH(?fecha_de_nacimiento) = MONTH(NOW()))
  FILTER(DAY(?fecha_de_nacimiento) = DAY(NOW()))

  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
ORDER BY ?peruanoLabel
Try it!

Datos lexicográficos

¿Cuáles son los gentilicios utilizados para cada parte del Perú?

#defaultView:Map
SELECT DISTINCT
  ?coordenadas
  ?ubicación
  ?ubicaciónLabel
  ?lexema
  ?lemma
{
  ?lexema
     dct:language wd:Q1321;
     wikibase:lemma ?lema;
     ontolex:sense/wdt:P6271 ?ubicación.

  ?ubicación
    wdt:P131* wd:Q419;
    wdt:P625 ?coordenadas.

  SERVICE wikibase:label {bd:serviceParam wikibase:language "es,qu,en"}.
}
Try it!

Ciencia

General

Revistas publicadas por instituciones que se encuentran en algún lugar del Perú

SELECT
  ?publicador
  ?publicadorLabel
  ?revista
  ?revistaLabel
WITH {
  SELECT DISTINCT ?publicador {
    ?publicador wdt:P131* wd:Q419.
  }
} AS %0
WITH {
  SELECT ?publicador ?revista {
    INCLUDE %0.
    ?revista wdt:P123 ?publicador.
  }
} AS %1
{
  INCLUDE %1.

  {?revista wdt:P31/wdt:P279* wd:Q5633421}
  UNION
  {?revista wdt:P31/wdt:P279* wd:Q737498}

  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
ORDER BY ASC(?publicadorLabel) ASC(?revistaLabel)
Try it!

Artículos científicos cuyos autores son peruanos y están vivos

SELECT
  ?elemento
  ?elementoLabel
  ?ocupaciónLabel
  ?artículo
  ?artículoLabel
{
  ?elemento wdt:P31 wd:Q5;
            wdt:P27 wd:Q419;
            wdt:P106 ?ocupación.
  ?artículo wdt:P50 ?elemento;
            wdt:P31 wd:Q13442814.
  FILTER NOT EXISTS{?elemento wdt:P570 ?fecha_de_fallecimiento}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY ASC(?elementoLabel)
Try it!

10 principales temas de artículos científicos publicados por peruanos

#defaultView:BarChart
SELECT
  ?temaLabel
  (COUNT(?temaLabel) AS ?conteo)
{
  {?peruano wdt:P27 wd:Q419 }
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419 }
  
  ?artículo wdt:P50 ?peruano;
            wdt:P31 wd:Q13442814;
            wdt:P921 ?tema.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
GROUP BY ?temaLabel
ORDER BY DESC(?conteo)
LIMIT 10
Try it!

Ciencia de la computación

¿Qué peruanos tienen GitHub username?

SELECT
  ?peruane
  ?peruaneLabel
  ?peruaneDescription
  ?usuarioDeGithub
WITH {
  SELECT DISTINCT ?peruane {
    {?peruane wdt:P27 wd:Q419 }
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruane wdt:P1532 wd:Q419}
  }
} AS %peruane
{
  INCLUDE %peruane.
  ?peruane wdt:P2037 ?usuarioDeGithub.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en"}.
}
ORDER BY ASC(?peruaneLabel)
Try it!

Científicos de la computación de Perú

SELECT DISTINCT
  ?peruano
  ?peruanoLabel
  ?fecha_de_nacimiento
  ?fecha_de_fallecimiento
{
  {?peruano wdt:P27 wd:Q419}
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419}

  ?peruano wdt:P106 wd:Q82594

  OPTIONAL{?peruano wdt:P569 ?fecha_de_nacimiento}
  OPTIONAL{?peruano wdt:P570 ?fecha_de_fallecimiento}

  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}
}
Try it!

Entidades que tienen relación directa con computer science y Peru

SELECT
  ?itemLabel
  ?property1Label
  ?property2Label
{
  ?property1 wikibase:directClaim ?wdt1.
  ?property2 wikibase:directClaim ?wdt2.

  ?item ?wdt1 wd:Q419;
        ?wdt2 wd:Q21198.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
Try it!

Entidades directamente relacionadas con Perú e indirectamente relacionadas con ciencias de la computación

SELECT
  ?elemento1
  ?elemento1Label
  ?propiedad1Label
  ?propiedad2Label
  ?elemento2
  ?elemento2Label
  ?propiedad3Label
{
  # Variables que nos ayudarán a escribir la consulta

  ?propiedad1 wikibase:directClaim ?wdt1.
  ?propiedad2 wikibase:directClaim ?wdt2.
  ?propiedad3 wikibase:directClaim ?wdt3.

  # El elemento debe tener relación directa con Perú
  ?elemento1 ?wdt1 wd:Q419;
             # El elemento debe estar relacionado con otro elemento
             ?wdt2 ?elemento2.

  # El elemento debe estar relacionado con Ciencia de la Computación
  ?elemento2 ?wdt3 wd:Q21198.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
Try it!

Género

¿Qué obras literarias han sido escritas por mujeres con nacionalidad peruana?

#defaultView:Tree
SELECT
  ?peruane
  ?peruaneLabel
  ?obraLiteraria
  ?obraLiterariaLabel
WITH {
  SELECT DISTINCT ?peruane {
    ?peruane
      wdt:P27 wd:Q419;
      wdt:P31 wd:Q5;
      wdt:P21 wd:Q6581072.
  }
} AS %0
WITH {
  SELECT DISTINCT ?obraLiteraria ?peruane {
    INCLUDE %0.

    ?obraLiteraria
      wdt:P50 ?peruane;
      wdt:P31/wdt:P279* wd:Q7725634.
  }
} AS %1
WITH {
  SELECT ?peruane (COUNT(*) AS ?count) {
    INCLUDE %1
  }
  GROUP BY ?peruane
} AS %2
{
  INCLUDE %1.
  INCLUDE %2.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es,qu,en"}.
}
ORDER BY DESC(?count)
Try it!

Política

¿Qué peruanes tienen ocupación de político o tienen ocupación a alguna de las subclases de político?

SELECT
  ?peruane
  ?peruaneLabel
  ?ocupación
  ?ocupaciónLabel
WITH {
  SELECT DISTINCT ?ocupación {
    ?ocupación wdt:P279* wd:Q82955.
  }
} AS %0
WITH {
  SELECT DISTINCT ?peruane ?ocupación {
    ?peruane
       wdt:P31 wd:Q5;
       wdt:P27 wd:Q419;
       wdt:P106 ?ocupación.
  }
} AS %1
WITH {
  SELECT ?peruane ?ocupación {
    INCLUDE %0.
    INCLUDE %1.
  }
} AS %2
{
  INCLUDE %2.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "[AUTO_LANGUAGE]"}.
}
ORDER BY ASC(LCASE(?peruaneLabel))
Try it!

Member of the Congress of the Republic of Peru que saben hablar Quechua

SELECT DISTINCT
  ?congresista
  ?congresistaLabel
  ?imagen 
{
  ?congresista
    wdt:P39 wd:Q18812470;
    # Buscamos la propiedad P103 o P1412 porque es posible que usuarios
    # hayan guardado la información usando cualquiera de estas
    # propiedades
    wdt:P103|wdt:P1412 wd:Q5218.

  # Opcionalmente, mostramos la imagen del congresista si es que existe
  OPTIONAL{?congresista wdt:P18 ?imagen}

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
Try it!

Member of the Congress of the Republic of Peru que ha estado en más partidos políticos

SELECT
  ?congresista
  ?congresistaLabel
  (COUNT(?congresista) AS ?count)
{
  ?congresista
    wdt:P39 wd:Q18812470;
    wdt:P102 ?partido_político.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
GROUP BY ?congresista ?congresistaLabel
ORDER BY DESC(?count)
Try it!

Línea de tiempo de los Ministro de Economía y Finanzas del Perú

#defaultView:Timeline
SELECT
  ?elemento
  ?elementoLabel
  ?fecha_de_inicio
{
  ?elemento p:P39 ?valor.
  ?valor ps:P39 wd:Q5195495;
         pq:P580 ?fecha_de_inicio.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
Try it!

Member of the Congress of the Republic of Peru que han sido condenados

SELECT
  ?elemento
  ?elementoLabel
  ?condenado_por
  ?condenado_porLabel
{
  ?elemento wdt:P39 wd:Q18812470;
            wdt:P1399 ?condenado_por.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
Try it!

Presidencia

Nombre del actual presidente del Perú en idiomas en donde el nombre es diferente

SELECT
  ?idioma
  ?nombre
{
  # Obtención del presidente actual
  #
  # Si no hay otro presidente cuya fecha de inicio es mayor al
  # encontrado, entonces el encontrado es el presidente actual.

  ?presidente wdt:P39 wd:Q5708511;
              p:P39 ?presidencia.
  ?presidencia pq:P580 ?fecha_de_inicio.

  FILTER NOT EXISTS {
    ?presidente2 wdt:P39 wd:Q5708511;
                 p:P39 ?presidencia2.
    ?presidencia2 pq:P580 ?fecha_de_inicio2.
    FILTER(?fecha_de_inicio2 > ?fecha_de_inicio)
  }

  # Obtención del nombre del presidente actual en Español

  ?presidente rdfs:label ?nombre_es;
              FILTER(LANG(?nombre_es) = "es").

  # Obtención del nombre del presidente actual en otros idiomas

  ?presidente rdfs:label ?nombre;
              FILTER(xsd:string(?nombre) != xsd:string(?nombre_es)).

  BIND(LANG(?nombre) AS ?idioma).
}
ORDER BY ?idioma
Try it!

Presidentes peruanos que han sido condenados

SELECT
  ?item
  ?itemLabel
  ?condenado_por
  ?condenado_porLabel
{
  ?item wdt:P39 wd:Q5708511;
        wdt:P1399 ?condenado_por.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
Try it!

Línea de tiempo de las elecciones presidenciales de Perú

#defaultView:Timeline
SELECT
  ?ganador
  ?ganadorLabel
  ?tiempo
{
  [] wdt:P31 wd:Q858439;
     wdt:P1001 wd:Q419;
     wdt:P991 ?ganador;
     wdt:P585 ?tiempo.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
Try it!

Línea de tiempo de presidentes de Perú

#defaultView:Timeline
SELECT
  ?elemento
  ?elementoLabel
  ?fecha_de_inicio
  ?fecha_de_fin
{ 
  ?elemento p:P39 ?posicion.
  ?posicion ps:P39 wd:Q5708511;
            pq:P580 ?fecha_de_inicio;
            pq:P582 ?fecha_de_fin.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
Try it!

Cultura

Misceláneo

¿Cuál es la cantidad de obras literarias por personas con nacionalidad peruana?

SELECT
  ?item
  ?itemLabel
  (COUNT(*) AS ?count)
WITH {
  SELECT DISTINCT ?item ?literaryWork {
    ?item
      wdt:P31 wd:Q5;
      wdt:P27 wd:Q419.
    ?literaryWork
      wdt:P31 wd:Q7725634;
      wdt:P50 ?item.
  }
} AS %0
{
  INCLUDE %0.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
GROUP BY ?item ?itemLabel
ORDER BY DESC(?count)
Try it! 
library('magrittr')
library('plotly')
library('httr')

query <- '
SELECT
  ?item
  ?itemLabel
  (COUNT(*) AS ?count)
WITH {
  SELECT DISTINCT ?item ?literaryWork {
    ?item
      wdt:P31 wd:Q5;
      wdt:P27 wd:Q419.
    ?literaryWork
      wdt:P31 wd:Q7725634;
      wdt:P50 ?item.
  }
} AS %0
{
  INCLUDE %0.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
GROUP BY ?item ?itemLabel
ORDER BY DESC(?count)
'

url <- paste('https://query.wikidata.org/sparql?query=', URLencode(query), sep='')

r <- GET(url, accept('text/csv'))

dat <- content(r)

dat <- dat[order(dat $ count, decreasing = FALSE),]

p <- plot_ly(
    type = 'parcoords',
    line = list(color = 'blue'),
    dimensions = list(
        list(label = 'Personas con nacionalidad peruana',
             range = nrow(dat),
             values = 1:nrow(dat),
             tickvals = 1:nrow(dat),
             ticktext = dat $ itemLabel),
        list(label = 'Número de obras literarias',
             range = c(min(dat $ count), max(dat $ count)),
             values = dat $ count))) %>%
    layout(margin = list(l = 200, r = 100))

¿Dónde están ubicadas las instituciones que le han otorgado algún premio a una mujer nacida en Perú?

#defaultView:Map
SELECT
  ?coordenadas
  ?institucion
  ?institucionLabel
  ?premio
  ?premioLabel
  ?mujer
  ?mujerLabel
WITH {
  SELECT DISTINCT ?mujer {
    ?mujer wdt:P19/wdt:P131* wd:Q419;
           wdt:P21 wd:Q6581072.
  }
} AS %0
WITH {
  SELECT DISTINCT ?mujer ?premio {
    INCLUDE %0.
    ?mujer wdt:P166 ?premio.
  }
} AS %1
WITH {
  SELECT DISTINCT ?institucion ?premio {
    INCLUDE %1.
    {?institucion wdt:P5460 ?premio}
    UNION
    {?premio wdt:P1027 ?institucion}.
  }
} AS %2
WITH {
  SELECT ?institucion ?coordenadas {
    INCLUDE %2.

    OPTIONAL{?institucion wdt:P625 ?coordenadasDirecto}.
    OPTIONAL{?institucion wdt:P159/wdt:P625 ?coordenadasSede}.
    OPTIONAL{?institucion wdt:P131/wdt:P625 ?coordenadasUbicacion}.

    # Si todas las condiciones dentro de COALESCE fallan, entonces el
    # valor de la variables será indefinido.

    BIND(COALESCE(IF(BOUND(?coordenadasDirecto), ?coordenadasDirecto, 1/0),
                  IF(BOUND(?coordenadasSede), ?coordenadasSede, 1/0),
                  IF(BOUND(?coordenadasUbicacion), ?coordenadasUbicacion, 1/0))
         AS ?coordenadas)

    # Solo mostraremos aquellas cuyas coordenadas se saben

    FILTER(BOUND(?coordenadas))
  }
} AS %3
{
  INCLUDE %1.
  INCLUDE %2.
  INCLUDE %3.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
Try it!

Con suficiente imaginación, uno puede abstraer la consulta de arriba para poder usarla para diferentes fines. Con la siguiente consulta, uno puede hacer análisis en cualquier conjunto de elementos que cumplen un conjunto de condiciones: biólogicos, científicos de la computación, matemáticos, personas nacidas en Japón, etc. 

#defaultView:Map
SELECT
  ?coordinates
  ?institution
  ?institutionLabel
  ?award
  ?awardLabel
  ?item
  ?itemLabel
WITH {
  SELECT DISTINCT ?item {
    ?item
      wdt:P19/wdt:P131* wd:Q419.
  }
} AS %0
WITH {
  SELECT DISTINCT ?item ?award {
    INCLUDE %0.
    ?item wdt:P166 ?award.
  }
} AS %1
WITH {
  SELECT DISTINCT ?institution ?award {
    INCLUDE %1.
    {?institution wdt:P5460 ?award}
    UNION
    {?award wdt:P1027 ?institution}.
  }
} AS %2
WITH {
  SELECT DISTINCT ?institution ?coordinates {
    INCLUDE %2.

    OPTIONAL{?institution wdt:P625 ?P625}.
    OPTIONAL{?institution wdt:P159/wdt:P625 ?P159_P625}.
    OPTIONAL{?institution wdt:P131+/wdt:P625 ?P131_P625}.

    BIND(COALESCE(IF(BOUND(?P625), ?P625, 1/0),
                  IF(BOUND(?P159_P625), ?P159_P625, 1/0),
                  IF(BOUND(?P131_P625), ?P131_P625, 1/0))
         AS ?coordinates)

    FILTER(BOUND(?coordinates))
  }
} AS %3
{
  INCLUDE %1.
  INCLUDE %2.
  INCLUDE %3.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "en"}.
}
Try it!

¿Qué sitios arqueólogicos se encuentran en Perú? y ¿A qué cultura pertenecieron?

#title: Sitios arqueólogicos ubicados en Perú y cultura a la que pertenecieron
#defaultView:Map
SELECT
  ?coordenadas
  ?item
  ?itemLabel
  ?cultura
  ?culturaLabel
# Primero, conseguimos las cosas ubicadas en Perú
WITH {
  SELECT DISTINCT ?item {
    ?item wdt:P131* wd:Q419.
  }
} AS %0
# Segundo, verificamos que son sitios arqueólogicos.
WITH {
  SELECT DISTINCT ?item {
    INCLUDE %0.
    ?item wdt:P31/wdt:P279* wd:Q839954.
  }
} AS %1
WITH {
  SELECT ?item ?cultura ?coordenadas {
    INCLUDE %1.
    ?item wdt:P2596 ?cultura;
          wdt:P625 ?coordenadas.
  }
} AS %2
{
  INCLUDE %2.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es,qu,en"}.
}
Sitios arqueólogicos ubicados en Perú y cultura a la que pertenecieron

Con la siguiente consulta, podemos listar aquellos sitios arqueólogicos que no son mostrados en el mapa debido a que no tienen las propiedades culture (P2596) o coordinate location (P625). 

SELECT
  ?item
  ?itemLabel
  ?cultura
  ?culturaLabel
  ?coordenadas
WITH {
  SELECT DISTINCT ?item {
    ?item wdt:P131* wd:Q419.
  }
} AS %0
WITH {
  SELECT DISTINCT ?item {
    INCLUDE %0.
    ?item wdt:P31/wdt:P279* wd:Q839954.
  }
} AS %1
WITH {
  SELECT ?item ?cultura ?coordenadas {
    INCLUDE %1.
    OPTIONAL{?item wdt:P2596 ?cultura}.
    OPTIONAL{?item wdt:P625 ?coordenadas}.
    FILTER(!BOUND(?cultura)|| !BOUND(?coordenadas)).
  }
} AS %2
{
  INCLUDE %2.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es,qu,en"}.
}
Try it!

¿Qué cosas han sido nombradas por peruanos y se encuentran en otros países?

#defaultView:Map
SELECT
  ?coordenadas
  ?pais
  ?paisLabel
  ?cosa
  ?cosaLabel
  ?peruane
  ?peruaneLabel
WITH {
  SELECT DISTINCT ?peruane {
    {?peruane wdt:P27 wd:Q419 }
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruane wdt:P1532 wd:Q419}
  }
} AS %0
WITH {
  SELECT DISTINCT ?cosa ?coordenadas ?peruane {
    INCLUDE %0.
    ?cosa wdt:P138 ?peruane;
          wdt:P625 ?coordenadas.
  }
} AS %1
WITH {
  SELECT DISTINCT ?pais ?cosa ?coordenadas ?peruane {
    INCLUDE %1.
    ?cosa (wdt:P276
Try it!

¿Cuál es la cantidad de cosas cuyos autores han sido peruanos y tienen artículo en Wikipedia en español por peruano?

SELECT
  ?autor
  ?autorLabel
  (COUNT(*) AS ?count)
WITH {
  SELECT DISTINCT ?autor {
    {?autor wdt:P27 wd:Q419}
    UNION
    {?autor wdt:P19/wdt:P131* wd:Q419}
    UNION
    {?autor wdt:P1532 wd:Q419}
  }
} AS %0
WITH {
  SELECT DISTINCT ?autor ?obra {
    INCLUDE %0.
    ?obra wdt:P50 ?autor.

    [] schema:about ?obra;
       schema:isPartOf <https://es.wikipedia.org/>.
  }
} AS %1
{
  INCLUDE %1.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
GROUP BY ?autor ?autorLabel
ORDER BY DESC(?count)
Try it!

¿Cuáles son las literary work publicada por cada peruano?

#defaultView:Tree
SELECT
  ?peruane
  ?peruaneLabel
  ?libro
  ?libroLabel
WITH {
  SELECT DISTINCT ?peruane {
    {?peruane wdt:P27 wd:Q419 }
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruane wdt:P1532 wd:Q419}
  }
} AS %0
WITH {
  SELECT DISTINCT ?libro ?peruane {
    INCLUDE %0.
    ?libro wdt:P31 wd:Q7725634;
           wdt:P50 ?peruane.
  }
} AS %1
{
  INCLUDE %1.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
ORDER BY ASC(?peruaneLabel)
Try it!

Árbol geneálogico de los ancestros de Atahualpa

#defaultView:Graph
SELECT
  ?nodo
  ?nodoLabel
  ?enlaceCon
  ?enlaceConLabel
  (?propiedadLabel AS ?edgeLabel)
{
  wd:Q179577 (wdt:P22|wdt:P25)* ?nodo.

  {?nodo p:P22 [ps:P22 ?enlaceCon; ?ps []].}
  UNION
  {?nodo p:P25 [ps:P25 ?enlaceCon; ?ps []].}

  ?property wikibase:statementProperty ?ps.

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "es".
    ?nodo rdfs:label ?nodoLabel.
    ?enlaceCon rdfs:label ?enlaceConLabel.
    ?property rdfs:label ?propiedadLabel.
  }
}
Try it!

Mapa de museum ubicados en Peru

#defaultView:Map
SELECT DISTINCT
  ?elemento
  ?elementoLabel
  ?coordenadas
{
  ?elemento wdt:P31/wdt:P279* wd:Q33506;
            wdt:P17 wd:Q419;
            wdt:P625 ?coordenadas.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Try it!

Películas

¿Qué películas han sido grabadas en algún lugar del Peru?

SELECT DISTINCT ?película ?películaLabel {
  ?película wdt:P31 wd:Q11424.
  ?película wdt:P915 ?lugarDeFilmación.
  ?lugarDeFilmación wdt:P131* wd:Q419.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
Try it!

La consulta mostrada arriba puede ser simplificada utilizando un camino de propiedades, como es mostrada en la siguiente consulta. Ambas consultas obtienen los mismos resultados. 

SELECT DISTINCT ?película ?películaLabel {
  ?película wdt:P31 wd:Q11424;
            wdt:P915/wdt:P131* wd:Q419.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
Try it!

¿Qué películas han sido grabadas en algún lugar del Peru y usan Quechua?

SELECT DISTINCT ?película ?películaLabel ?películaDescription {
  ?película wdt:P31 wd:Q11424.
  ?película wdt:P364|wdt:P407 wd:Q5218.
  ?película wdt:P915/wdt:P131* wd:Q419.

  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}
}
Try it!

La consulta mostrada arriba puede ser simplificada utilizando el caractér ;, como es mostrado en la consulta de abajo. Ambas consultas obtienen los mismos resultados. 

SELECT DISTINCT ?película ?películaLabel ?películaDescription {
  ?película wdt:P31 wd:Q11424;
            wdt:P364|wdt:P407 wd:Q5218;
            wdt:P915/wdt:P131* wd:Q419.

  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}
}
Try it!

¿Qué películas han tenido como director a alguien que nació en Peru?

SELECT DISTINCT ?película ?películaLabel {
  ?película wdt:P31 wd:Q11424.
  ?película wdt:P57 ?director.
  ?director wdt:P19 ?lugarDeNacimiento.
  ?lugarDeNacimiento wdt:P131* wd:Q419.

  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
Try it!

La consulta mostrada arriba puede ser simplificada usando un camino de propiedades, como es mostrado en la consulta de abajo. Ambas consultas obtienen el mismo resultado. 

SELECT DISTINCT ?película ?películaLabel {
  ?película wdt:P31 wd:Q11424;
            wdt:P57/wdt:P19/wdt:P131* wd:Q419.

  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
Try it!

¿Qué películas han sido hechas por alguna productora que tiene su sede en alguna parte del Peru?

SELECT DISTINCT ?película ?películaLabel ?películaDescription {
  ?película wdt:P31 wd:Q11424.
  ?película wdt:P272 ?empresaProductora.
  ?empresaProductora wdt:P159 ?ubicaciónSede.
  ?ubicaciónSede wdt:P131* wd:Q419.

  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
Try it!

La consulta mostrada arriba puede ser simplificado utilizando el camino de propiedades, como es mostrado en la siguiente consulta. 

SELECT DISTINCT ?película ?películaLabel ?películaDescription{
  ?película wdt:P31 wd:Q11424;
            wdt:P272/wdt:P159/wdt:P131* wd:Q419.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
Try it!

Comida

¿Qué imágenes en Wikimedia Commons muestran platos de la peruvian cuisine?

#defaultView:ImageGrid
SELECT
  ?imagen
  ?plato
  ?platoLabel
WITH {
  SELECT DISTINCT ?plato {
    SERVICE <https://query.wikidata.org/sparql> {
      ?plato wdt:P361 wd:Q749847.
    }
  }
} AS %plato
WITH {
  SELECT ?plato ?platoLabel {
    INCLUDE %plato.
    SERVICE <https://query.wikidata.org/sparql> {
      {
        SELECT ?plato ?platoLabel {
          SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
        }
      }
    }
  }
} AS %platoLabel
WITH {
  SELECT DISTINCT ?imagen ?plato {
    INCLUDE %plato.
    [] wdt:P180 ?plato;
       schema:url ?imagen.
  }
} AS %imagen
{
  INCLUDE %platoLabel
  INCLUDE %imagen.
}
ORDER BY ASC(LCASE(?platoLabel))
Try it!

¿Cuál es la cantidad, para cada plato de la peruvian cuisine, de imágenes en Wikimedia Commons que muestran a esos platos?

SELECT
  ?plato
  ?platoLabel
  ?conteo
WITH {
  SELECT DISTINCT ?plato {
    SERVICE <https://query.wikidata.org/sparql> {
      ?plato wdt:P361 wd:Q749847.
    }
  }
} AS %plato
WITH {
  SELECT ?plato ?platoLabel {
    INCLUDE %plato.
    SERVICE <https://query.wikidata.org/sparql> {
      {
        SELECT ?plato ?platoLabel {
          SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
        }
      }
    }
  }
} AS %platoLabel
WITH {
  SELECT DISTINCT ?imagen ?plato {
    INCLUDE %plato.
    ?imagen wdt:P180 ?plato.
  }
} AS %imagen
WITH {
  SELECT ?plato (COUNT(*) AS ?conteo) {
    INCLUDE %imagen.
  }
  GROUP BY ?plato
} AS %conteo
{
  INCLUDE %platoLabel.
  OPTIONAL{INCLUDE %conteo}.
}
ORDER BY DESC(?conteo)
Try it!

¿Cuál es la cantidad, para cada plato de la peruvian cuisine, de imágenes que existen en la entidad del plato con la propiedad image (P18)?

SELECT
  ?plato
  ?platoLabel
  ?conteo
WITH {
  SELECT DISTINCT ?plato {
    ?plato wdt:P361 wd:Q749847;
  }
} AS %plato
WITH {
  SELECT
    ?plato
    (COUNT(*) AS ?conteo)
  {
    INCLUDE %plato.
    ?plato wdt:P18 ?imagen.
  }
  GROUP BY ?plato
} AS %conteo
{
  INCLUDE %plato.
  OPTIONAL{INCLUDE %conteo}.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
ORDER BY DESC(?conteo)
Try it!

Historia

Línea de tiempo de las guerras en las que ha participado Perú

#defaultView:Timeline
SELECT
  ?guerra
  ?guerraLabel
  ?fecha_de_inicio
  ?fecha_de_fin
{
  ?guerra wdt:P31 wd:Q198;
          wdt:P710 wd:Q419;
          wdt:P580 ?fecha_de_inicio;
          wdt:P582 ?fecha_de_fin.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
Try it!

Literatura

¿Cuál es la cantidad de obras literaria publicadas por cada peruane?

SELECT
  ?peruane
  ?peruaneLabel
  ?conteo
WITH {
  SELECT DISTINCT ?peruane {
    {?peruane wdt:P27 wd:Q419}
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419}
    UNION
    {?peruane wdt:P1532 wd:Q419}
  }
} AS %0
WITH {
  SELECT ?peruane (COUNT(*) AS ?conteo) {
    INCLUDE %0.
    [] wdt:P50 ?peruane;
       wdt:P31/wdt:P279* wd:Q7725634.
  }
  GROUP BY ?peruane
} AS %1
{
  INCLUDE %1.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
ORDER BY DESC(?conteo)
Try it!

Tabla de frecuencia de lugares por nacimiento de autores de obras literarias

SELECT
  ?lugarDeNacimiento
  ?lugarDeNacimientoLabel
  ?conteo
WITH {
  SELECT DISTINCT ?peruane {
    {?peruane wdt:P27 wd:Q419}
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419}
    UNION
    {?peruane wdt:P1532 wd:Q419}
  }
} AS %0
WITH {
  SELECT ?peruane {
    INCLUDE %0.

    []
      wdt:P50 ?peruane;
      wdt:P31/wdt:P279* wd:Q7725634.
  }
} AS %1
WITH {
  SELECT ?lugarDeNacimiento (COUNT(*) AS ?conteo) {
    INCLUDE %1
    ?peruane wdt:P19 ?lugarDeNacimiento.
  }
  GROUP BY ?lugarDeNacimiento
} AS %2
{
  INCLUDE %2.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
ORDER BY DESC(?conteo)
Try it!

¿Cuál es la cantidad de enlaces de sitio para cada obra literaria escrita por peruanos?

SELECT
  ?obraLiteraria
  ?obraLiterariaLabel
  ?cantidad
WITH {
  SELECT DISTINCT ?peruane {
    {?peruane wdt:P27 wd:Q419 }
    UNION
    {?peruane wdt:P19/wdt:P131* wd:Q419 }
    UNION
    {?peruane wdt:P1532 wd:Q419}
  }
} AS %0
WITH {
  SELECT DISTINCT ?peruane ?obraLiteraria {
    INCLUDE %0.
    ?obraLiteraria
      wdt:P50 ?peruane;
      wdt:P31/wdt:P279* wd:Q7725634.
  }
} AS %1
WITH {
  SELECT DISTINCT ?obraLiteraria ?cantidad {
    INCLUDE %1.
    ?obraLiteraria wikibase:sitelinks ?cantidad.
  }
} AS %2
{
  INCLUDE %1.
  OPTIONAL{INCLUDE %2}.
  SERVICE wikibase:label {bd:serviceParam wikibase:language "es"}.
}
ORDER BY DESC(?cantidad)
Try it!

Wikimedia

Misceláneo

WikiProject enfocados en temas relacionados a Peru

La lista generada por esta consulta puede mostrarle a una persona la gran variedad de proyectos enfocados en Peru (Q419). Así, dicha persona se sentirá más motivada a contribuir pues podrá escoger el tema en el que se sienta más cómodo. 

SELECT DISTINCT
  ?proyecto
  ?proyectoLabel
  ?proyectoDescription
  ?tema
  ?temaLabel
{
  ?proyecto
    # Instancias de Wikiproyectos o de alguna subclase de
    # Wikiproyectos
    wdt:P31/wdt:P279* wd:Q16695773;
    wdt:P921|wdt:P101 ?tema.

  # El tema principal debe ser Perú o alguna entidad que sea "parte
  # de" (P361) o "país" (P17) Perú.

  { VALUES ?tema {wd:Q419} }
  UNION
  {?tema wdt:P361 | wdt:P17 wd:Q419}

  # Escondemos los que tienen fecha de fin, porque solo nos interesan
  # los proyectos vigentes
  #
  # Tarea pendiente: Listar los eventos cuya fecha de fin sean pasados
  # a la fecha actual. Pueden haber proyectos que están destinados a
  # terminar en una fecha.

  FILTER NOT EXISTS {
    ?proyecto wdt:P582 [].
  }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
ORDER BY DESC(?proyectoLabel)
Try it!

Editatones

Editatones de Perú

SELECT
  ?elemento
  ?elementoLabel
  ?tema_principalLabel
  ?año
  ?artículo
{
  ?elemento wdt:P31 wd:Q16022392;
            wdt:P17 wd:Q419;
            wdt:P921 ?tema_principal;
            wdt:P580 ?fecha_de_inicio.
  ?artículo schema:about ?elemento;
            schema:isPartOf <https://es.wikipedia.org/>.
  BIND(YEAR(?fecha_de_inicio) AS ?año)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es". }
}
ORDER BY DESC(?año)
Try it!

Línea de tiempo de las editatones de Perú

#defaultView:Timeline
SELECT
  ?item
  ?itemLabel
  ?article
  ?topics
  ?st
  ?et
{
  {
    SELECT
      ?item
      (GROUP_CONCAT(DISTINCT ?msLabel; SEPARATOR = ", ") AS ?topics)
    {
      ?item wdt:P31 wd:Q16022392;
            wdt:P17 wd:Q419;
            wdt:P921 ?ms.
      ?ms rdfs:label ?msLabel;
          FILTER(LANG(?msLabel) = "es").
    }
    GROUP BY ?item
  }
  {
    SELECT
      ?item
      ?itemLabel
      ?article
      ?st
      ?et
    {
      ?item wdt:P31 wd:Q16022392;
            wdt:P580 ?st;
            wdt:P582 ?et;
            rdfs:label ?itemLabel;
            FILTER(LANG(?itemLabel) = "es").
      ?article schema:about ?item.
    }
  }
}
Try it!

Número de editatones de Perú organizadas por año

#defaultView:BarChart
SELECT
  ?year_st
  (COUNT(?year_st) AS ?count)
{
  ?item wdt:P31 wd:Q16022392;
        wdt:P17 wd:Q419;
        wdt:P580 ?st.
  BIND(CONCAT("Año ", STR(YEAR(?st))) AS ?year_st).

}
GROUP BY ?year_st
Try it!

Gráfico de burbuja de las temáticas de las editatones de Perú

#defaultView:BubbleChart
SELECT
  ?msLabel
  (COUNT(?msLabel) AS ?count)
{
  ?item wdt:P31 wd:Q16022392;
        wdt:P17 wd:Q419;
        wdt:P921 ?ms.
  ?ms rdfs:label ?msLabel;
      FILTER(LANG(?msLabel) = "es")
}
GROUP BY ?msLabel
Try it!

Anexo

Consultas que exceden el límite de tiempo

Esta sección contiene consultas que resultan en «Query timeout limit reached» y, por lo tanto, es necesario que un usuario la optimice.

Patrimonio neto de peruanos ordenado descendentemente

SELECT DISTINCT
  ?peruano
  ?peruanoLabel
  ?peruanoDescription
  ?patrimonio_neto
{
  {?peruano wdt:P27 wd:Q419 }
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419 }

  ?peruano wdt:P2218 ?patrimonio_neto.
}
ORDER BY DESC(?patrimonio_neto)
Try it!

Puestos de peruanos en las versiones de UCI World Ranking

SELECT DISTINCT
  ?peruano
  ?peruanoLabel
  ?uci
  ?uciLabel
  ?puesto
{
  {?peruano wdt:P27 wd:Q419 }
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419 }
 
  ?uci wdt:P361 wd:Q21857512.
  
  ?peruano wdt:P1344 ?uci;
           p:P1344 ?participación_enunciado.

  ?participación_enunciado ps:P1344 ?uci;
                           pq:P1352 ?puesto.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
ORDER BY ASC(?puesto)
Try it!

Deportes en los que Perú tiene más medallas en los Olympic Games

SELECT DISTINCT
  ?deporte
  ?deporteLabel
  (COUNT(?deporte) AS ?count)
{
  # Campeones en los Juegos Olímpicos

  ?juego_olímpico
    wdt:P31/wdt:P279* wd:Q18536594;
    wdt:P641 ?deporte;
    p:P1346 ?declaración.

  ?declaración
    ps:P1346 ?campeón;
    pq:P642 ?medalla.
  
  # El valor de la variable "medalla" debe ser un valor que exprese posición en los 3 primeros puestos

  VALUES ?medalla {
    # Primer puesto
    wd:Q15243387
    wd:Q20882667
    # Segundo puesto
    wd:Q15889641
    wd:Q20882668
    # Tercer puesto
    wd:Q15889643
    wd:Q20882669
  }
  
  # El campeón debe ser un peruano
  
  {?campeón wdt:P27 wd:Q419 }
  UNION
  {?campeón wdt:P19/wdt:P131* wd:Q419 }

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?deporte ?deporteLabel
Try it!


Consultas terminadas con muy pocos datos

Esta sección contiene consultas que se ejecutan satisfactoriamente. Sin embargo, muestran cero o muy pocos datos.

Deportistas peruanos que han obtenido el primer puesto en cualquier competencia este año

SELECT DISTINCT
  ?peruano
  ?peruanoLabel
  ?puesto
  ?evento
  ?eventoLabel
{ 
  ?deporte wdt:P31/wdt:P279* wd:Q2312410;
           wdt:P3095 ?deportista.

  {?peruano wdt:P27 wd:Q419 }
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419 }
  
  ?peruano wdt:P27 wd:Q419;
           wdt:P106 ?deportista;
           p:P1344 ?evento_enunciado.

  ?evento_enunciado ps:P1344 ?evento;
                    pq:P1352 ?puesto.
  
  ?evento wdt:P585 ?tiempo.
  
  FILTER(YEAR(?tiempo) = YEAR(NOW()))
  FILTER(?puesto = 1)
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,[AUTO_LANGUAGE]". }
}
Try it!

Peruanos que han ganado medallas de oro en los Olympic Games

Perú tiene una medalla de oro. Sin embargo, esta consulta muestra cero. 

SELECT
  ?elemento
  ?elementoLabel
  ?campeón
  ?campeónLabel
{
  # Ganadores de medalla de oro en algún evento de los Juegos Olímpicos

  ?elemento
    wdt:P31/wdt:P279* wd:Q18536594;
    p:P1346 ?declaración.
  
  ?declaración
    ps:P1346 ?campeón;
    pq:P642 wdt:Q15243387.
    
  # Ganadores peruanos

  {?campeón wdt:P27 wd:Q419 }
  UNION
  {?campeón wdt:P19/wdt:P131* wd:Q419 }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

Deportistas peruanos que practican deportes individuales

En esta consulta, se deberían mostrar a deportistas peruanos que practican tennis, table tennis o horse racing. 

SELECT DISTINCT
  ?peruano
  ?peruanoLabel
  ?practicado_por
  ?practicado_porLabel
{
  ?deporte wdt:P31/wdt:P279* wd:Q2755547;
           wdt:P3095 ?practicado_por.

  {?peruano wdt:P27 wd:Q419 }
  UNION
  {?peruano wdt:P19/wdt:P131* wd:Q419 }

  ?peruano wdt:P106 ?practicado_por.

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
}
Try it!

Consultas sin categoría

Entidades relacionadas con Perú cuyo nombre tiene "oder"

Un usuario podría usar esta consulta para encontrar el "Poder Judicial del Perú", si es que, por alguna razón, la barra de búsqueda no lo muestra. 

SELECT
  ?item
  ?itemLabel
{
  ?property wikibase:directClaim ?wdt.
  ?item ?wdt wd:Q419;
        rdfs:label ?itemLabel;
        FILTER(LANG(?itemLabel) = "es").
  FILTER(REGEX(STR(?itemLabel), "oder", "i")).
}
Try it!

Ideas para consultas

Esta sección contiene ideas de consultas para que sea incluida en esta lista de ejemplos.

  • Cantidad de montañas por departamento.
  • Supermercados con tiendas en Perú con el menor ratio entre productos producidos y productos con octógonos
  • Buses que pasan por la Av. Javier Prado y por la Av. La Marina
  • Organizaciones voluntarias que operan en Perú
  • Películas grabadas en algún lugar del Perú
  • Peruanos con mayor cantidad de imágenes en Wikimedia Commons
  • Cantidad de premios recibidos por deportistas peruanos por año
  • Construcciones en Perú que han ganado algún premio
  • Peruanos que trabajan en empresas que han estado en los 10 primeros puestos del ranking de Alexa
  • Leyes peruanos cuyo primer artículo hace una declaración de heroe nacional del Perú
  • Especies que son consideradas venenosas y habitan en la amazonía de Perú
  • Especies que han sido descubiertas en Perú
  • Taxones cuyo nombre contiene la palabra «peruvianus»
  • Artículos científicos de biología de autores peruanos
  • Ministerios del Perú
  • Cantidad de cambio de ministros por Ministerio en los últimos 10 años
  • Canciones que han ganado premios y cuyos autores son peruanos
  • Áreas protegidas del Perú
  • Platos del Perú que utilizan cebolla
  • Bebidas del Perú que utilizan limón
  • Empresas en Perú que fabrican más productos con los octógonos
  • Galletas vendidas en Perú que tienen cualquiera de los octógonos
  • Productos fabricados en Perú que tienen los 3 octógonos
  • Causa de muertes de heroes peruanos
  • Cantidad de publicaciones por historiadores peruanos
  • Participantes del Imperio Incaico
  • Gráfico de barras de cantidad de masacres por departamento de Perú
  • Restaurantes que venden anticuchos y picarones y que en un radio de 100 metros hay un emolientero
Retrieved from "https://www.wikidata.org/w/index.php?title=Wikidata:SPARQL_query_service/queries/examples/Peru&oldid=1691010377"